Suite à une crash du client hier certains de mes addons se sont dé-configuré et j'ai du repasser du temps à les re-configurer.
Du coup je me suis fait un petit script qui va sauvegarder votre dossier WTF puis lancer WoW.
Il fait maximum un fichier zip par jour.

Créez un fichier myLauncher.bat à la racine du dossier d'installation de WoW et utilisez celui-ci pour lancer le jeu (remplacez votre icone sur le bureau par un raccourci vers ce fichier)

Code: Tout sélectionner

@echo off
REM ----- Setup -----
set SRC_DIR=.\WTF
set VBS_FILE=.\_zipIt.vbs
set ARCHIVE_FOLDER=".\WTF_Archives"
mkdir %ARCHIVE_FOLDER% 2> nul
set DATE_TIME=%DATE:~-4%.%DATE:~3,2%.%DATE:~0,2%
rem If you want full date-time : set DATE_TIME=%DATE:~-4%.%DATE:~3,2%.%DATE:~0,2%-%TIME:~0,2%.%TIME:~3,2%.%TIME:~6,2%
set ZIP_FILE="%ARCHIVE_FOLDER%\WTF_%DATE_TIME%.zip"
set WOW_PATH=.\WoW.exe

REM ----- Write VBS file -----
REM source : http://superuser.com/questions/110991/can-you-zip-a-file-from-the-command-prompt-using-only-windows-built-in-capabili
echo Set objArgs = WScript.Arguments > %VBS_FILE%
echo InputFolder = objArgs(0) >> %VBS_FILE%
echo ZipFile = objArgs(1) >> %VBS_FILE%

REM -- Get absolute path from relative path --
REM source :  http://stackoverflow.com/questions/15621395/vbscript-relative-path
echo set fso = CreateObject("Scripting.FileSystemObject") >> %VBS_FILE%
echo fullPathToSrc = fso.GetAbsolutePathName(InputFolder) >> %VBS_FILE%
echo fullPathToZip = fso.GetAbsolutePathName(ZipFile) >> %VBS_FILE%

echo CreateObject("Scripting.FileSystemObject").CreateTextFile(ZipFile, True).Write "PK" ^& Chr(5) ^& Chr(6) ^& String(18, vbNullChar) >> %VBS_FILE%
echo Set objShell = CreateObject("Shell.Application") >> %VBS_FILE%
echo Set source = objShell.NameSpace(fullPathToSrc).Items >> %VBS_FILE%
echo objShell.NameSpace(fullPathToZip).CopyHere(source) >> %VBS_FILE%
echo wScript.Sleep 500 >> %VBS_FILE%

REM ----- Execute VBS file (creating ZIP file) -----
CScript %VBS_FILE% %SRC_DIR% %ZIP_FILE%

REM ----- Delete VBS file -----
del %VBS_FILE%

REM ----- Launch WoW -----
start %WOW_PATH%

Je commence la phase de test de ce script en ce moment, je reviendrai peut-être mettre à jour le sujet si j'y trouve des bugs.

Bonjour ,
je suis intéressé par ton script, mais je suis une brêle en prog ,
ton fichier , si j' ai bien compris , n' a nul besoin d' être modifié en fonction de nos adds c est bien ca ?

En effet il n'y a rien à modifier.
Tu crées un fichier texte, tu remplaces l'extention ".txt" par ".bat", tu colles tout le bordel que j'ai cité au-dessus et roule ma poule ^^
Pour vérifier que ça fonctionne bien, une fois que tu double-clique sur le fichier .bat, ça crée un dossier WTF_Archives à la racine, juste en dessous de WTF. Et dedans y'aura un .zip.

merci beaucoup :)

pour l utilisation les explications etaient assez claires

j ai quelques mauvais souvenirs de chez blizzard quand y avait crash (-les fenetres de partout et 1 h pour tout remettre en ordre :'( - )
et j ai deja eu quelques crashs ici donc MERCIII

De rien. N'hésite pas à demander de l'aide si tu as des soucis.

Amazing !

Sympa,
Y a pas longtemps j'avais un soft assez similaire qui faisait la sauvegarde sur DropBox si tu cherche des pistes pour améliorer ^^

Dis toujours, mais je souhaite que mon script reste le plus simple possible.

il suffit de changer le chemin de Archive_Folder pour pointer vers le dossier de DropBox mais bon ça te fait faire 2 scripts différent pour ceux qui l'ont pas si tu veux garder un code simple ^^