Bonjour, voici un sujet regroupant toutes les macros utilisées en PvP uniquement. Il a pour but d'aider les nouveaux joueurs comme les meilleurs et offre une possibilité de débat à propos des macros.
Seront listées ci-dessous toutes les macros jugées utiles/importantes pour le PvP et leur fonctionnalité.
Pour l'instant les noms des sorts sont en version anglaise, je les traduirai quand j'aurai le temps.
Toute contribution sera étudiée et ajoutée aux posts afin de regrouper les macros ce qui offre une meilleur lisibilité.
Contributeurs: Xxzergdeadqt, Cersei, Kuxy. Merci à vous!
Première macro basique :
/focus
Elle déterminera votre cible comme le "focus". C'est à dire une cible qui n'est pas la principale mais tout de même enregistrée par le jeu comme cible secondaire. Il est nécessaire d'avoir un add-on (FocusFrame) afin de pouvoir afficher cette cible sur votre interface. Combinez FocusFrame à Quartz par exemple pour afficher les barres de sorts de votre cible Focus.
/focus [target=mouseover, exists, harm] [target=target]
Focus le mouseover si c'est un ennemi, si aucun mouseover alors la cible devient le focus et si aucune cible ni mouseover le focus actuel disparait simplement.
/cleartarget [target=target, dead]
/clearfocus [target=focus, dead]
/target focus
/cleartarget [target=focus, noexists]
/targetlasttarget
/focus target
/targetlasttarget
Permute le focus et la cible et enlève la cible et/ou le focus si ils sont morts.
#showtooltip Shadowstep
/cast [target=focus] Shadowstep
/cast [target=focus] Kick
Un kick à distance sur votre focus sans changer de cible manuellement. Le Shadowstep est le Pas de l'ombre.
#showtooltip Blind
/targetenemy
/cast Blind
Rarement utilisée, j'ai pensé à cette macro pour les cas où je veux Cécité un rogue en camouflage que je vois tout à coup près de moi sans l'avoir ciblé au préalable. C'est aussi utilisable pour blind l'ennemi le plus proche sans avoir à changer manuellement de cible.
#showtooltip Gouge
/targetenemy
/cast Gouge
Pareil qu'au-dessus. Je l'utilise surtout pour suriner une cible qui n'est pas ma cible actuelle ni mon focus sans changer de cible manuellement. Utile en bg.
#showtooltip
/cast [target=focus] Shadowstep
/cast [target=focus] Sap
Pour procéder à un sap focus rapidement à la suite d'un autre contrôle. Le Pas de l'ombre n'est nécessaire que si vous manquez de temps pour atteindre la cible avant qu'elle se remette en combat.
#showtooltip Blind
/cast [target=focus] Shadowstep
/cast [target=focus] Blind
Peu utilisée, elle s'avère quand même nécessaire quand vous avez besoin de Cécité un prêtre chaud du slip sur les sw:d ou un druid qui reste à l'autre bout de la map pendant l'arène.
#showtooltip Shadowstep
/cast Shadowstep
/cast Cheap Shot
Remplacer coup bas par garrot pour une autre macro. Je les utilise car je suis un flemmard et préfère appuyer sur une seule touche pour performer des actions. Je la préfère aussi a un pas de l'ombre/coup bas manuel sur une cible qui camp dans une fusée de chasseur, question de latence ou de lag.
#showtooltip
/targetenemy [nocombat]
/cast Shadowstep
/cast Sap
Cible l'ennemi hors combat le plus proche et lance un Pas de l'ombre to sap.
#showtooltip
/cast Expose Armor
/stopattack
On aime bien en rogue utiliser ce genre d'open Coup bas+exposer armure, ou garrot+rupture sur un sap avant de rentamer la cible. Mais des fois le sap casse sur l'exposer armure ou la rupture car un coup blanc part tout seul. Plus de problème avec cette macro. Attention quand même au coup bas et garrot qui laissent les coups blancs partir tout seuls.
#showtooltip
/cast [nomodifier] Cloak of Shadows
/cast [modifier:shift] Blind
/cast [target=focus][modifier:ctrl] Blind
Un simple exemple de ce qu'on peut faire avec les [modifier] ce qui facilite vraiment la vie.
#showtooltip
/cast [target=focus] !Shiv
Utile pour appliquer sur le focus un poison ralentissant/qui ralentit la vitesse de cast. Attention cependant car vous perdrez vos points de combo sur votre cible actuelle. Pensez à les utiliser (Débiter etc) avant de faire cette action.
#showtooltip
/cast [nomodifier] Gouge
/cast [target=focus][modifier:shift] Gouge
Macro pour Suriner votre cible/focus sans perdre votre cible actuelle. Même remarque qu'au-dessus concernant les points de combo.
#showtooltip
/cast [nomodifier] Kick
/cast [target=focus][modifier:shift] Kick
Macro pour Kick votre cible/focus sans perdre votre cible actuelle.
#showtooltip Premeditation
/cast !Premeditation
/cast !Cheap Shot
Je l'utilise comme open de base pour Coup bas ainsi que Garrot. Dans 99% des cas je l'utilise par défaut, mais je garde tout de même les opens sans Préméditation pour des cas divers.
#showtooltip Sap
/targetenemy [noexists, nocombat]
/cast [exists, nocombat] !Sap
/cleartarget
La macro pour sap les autres rogues. Ou n'importe qui se trouvant dans votre chemin.
/cast [nomodifier] !Stealth
/cast [modifier:shift] Stealth
Cette macro vous empêche de casser le camouflage même en spammant votre macro.
Pour le casser un simple shift+click.
#showtooltip Blind
/stopattack [mod:ctrl]
/cleartarget [mod:ctrl]
/targetenemyplayer [mod:ctrl]
/cast [nomod][mod:ctrl][mod:alt,target=focus] Blind
Un click pour blind votre target. Un alt+click blind votre focus. Elle vous permet de blind des joueurs qui ne "peuvent pas" être pris pour cible avec ctrl+click (rogue en camouflage, chasseur qui feint la mort...).
#showtooltip [stance] Cheap Shot; Shiv
/cast [nomod,stance] Premeditation
/cast [nomod,stance][mod:alt,target=focus,stance] Cheap Shot; [nomod][mod:alt,target=focus] Shiv
/cast [nomod,nostance][mod:alt,target=focus,nostance] Throw
Lance Préméditation et Coup Bas en camouflage, sinon Kriss. À distance, Lancer (de couteau) sera lancé.
Un alt+click lancera ces sorts sur votre focus.
#showtooltip
/cast [nostance,nocombat] !Stealth; [nostance] Vanish
/cast [target=focus] Sap
Lance Camouflage si vous êtes hors combat, sinon Disparition (non camouflé).
Lance aussi Assommer sur votre focus.
#showtooltip [stance] Garrote; Hemorrhage
/startattack [nostance]
/cast [nomod,stance][mod:alt,target=focus] Premeditation
/cast [nomod,stance][mod:alt,target=focus,stance] Garrote; [nomod][mod:alt,target=focus] Hemorrhage
Lance Préméditation et Garrot en camouflage, sinon Hémorragie.
Un alt+click lancera ces mêmes actions sur votre focus.
#showtooltip Kick
/cast [mod:shift,target=focus] Shadowstep
/cast [nomod][mod:alt/shift,target=focus] Kick
/cast [mod:ctrl, target=target] Shadowstep
/cast [mod:ctrl, target=target] Kick
Un click lancera Kick sur votre cible.
Alt+click lancera Kick sur votre focus.
Shift+click lancera Pas de L'ombre+Kick sur votre focus.
Ctrl+click lancera Pas de L'ombre+Kick sur votre cible.
#showtooltip Preparation
/castsequence reset=10 !Sprint, null
/stopcasting
/cast Preparation
Macro très sympa qui lancera votre Sprint avant Préparation au cas où vous ne l'auriez pas utilisé auparavant.
#showtooltip Vanish
/cast [nocombat] !Stealth; [nostealth] Vanish
/cast [mod:shift][mod:alt,target=focus] Cheap Shot; [mod:ctrl] Garrote
/cast [nomod,target=focus] Sap
Un click lancera Disparition si vous êtes en combat (non camouflé), sinon Camouflage.
Elle essaiera aussi de Sap votre focus si c'est possible.
Un shift+click lancera Disparition + Coup Bas sur votre cible.
Un alt+click lancera Coup Bas sur votre focus.
Un ctrl+click lancera Garrot sur votre focus.
#showtooltip [stance] Sap; Gouge
/stopattack
/cleartarget
/targetenemyplayer
/cast [nomod,stance][mod:alt,target=focus,stance] Sap; [nomod][mod:alt,target=focus] Gouge
/cast [nocombat] !Stealth
Un click lancera Assommer en camouflage, sinon Suriner sur votre cible. Si hors combat, lance Camouflage.
Alt+click lancera ces mêmes actions sur votre focus.
Elle permet de sap/suriner des ennemis qui ne "peuvent pas" être pris pour cible (rogue en camouflage, chasseur qui feint la mort...).
#showtooltip VotreTrinketPvP
/cast [nomod][mod:ctrl] VotreTrinketPvP
/cast [nomod] !Stealth; [mod:ctrl] Gouge
Un click utilisera votre trinket PvP et lancera Camouflage.
Un ctrl+click utilisera votre trinket PvP et lancera Suriner sur votre cible (idéal en rogue vs. rogue par exemple).
Veillez à bien être incapable de lancer les sorts (Camouflage / Suriner) quand vous utilisez cette macro, car l'action lancée en premier est le sort, le trinket s'utilisera après.
#showtooltip
/equipslot 17 Arme1M
/cast Shiv
La macro consiste à équiper l'arme et lancer l'attaque Kriss en un seul click.
Le but de cette macro est d'en créer plusieurs (3 pour le mieux) afin d'appliquer selon les besoins les poisons voulus. Il vous faudra donc disposer de 3 armes mains gauches différentes et si possible les plus rapides possibles pour un coût de Kriss moindre. Appliquez ensuite sur chaque arme vos poisons, Ralentissant/Réduction de heal/Réduction du temps de cast et utilisez les à bon escient. Certains rogues utilisent même 4 armes pour le poison Mortel qui à mon sens n'est qu'une perte de dps.
/use Wound Poison V
/use 16
Applique le poison choisi sur votre main droite.
/use Crippling Poison II
/use 17
Applique le poison choisi sur votre main gauche.
Remplacez le poison par celui dont vous avez besoin.